Supplemental Material
Nonmem code of the two-target simulation model
$PROBLEM QSS+MM model
$INPUT C,ID,TIME,AMT,DV,LDV,EVID,MDV,CMT,TYPE
$DATA ../../Data/DerivedData/SimulatedNonmemDataQSS2.csv IGNORE = C
$SUBROUTINES ADVAN13 TOL=9
$MODEL
COMP(COMP1)
COMP(COMP2)
COMP(COMP3)
COMP(COMP4)
$PK
CL = THETA(1)*EXP(ETA(1))
V1 = THETA(2)*EXP(ETA(2))
Q = THETA(3)*EXP(ETA(3))
V2 = THETA(4)*EXP(ETA(4))
K = CL/V1
K12 = Q/V1
K21 = Q/V2
F1 = THETA(5)
KA = THETA(6)*EXP(ETA(5))
VM = THETA(7)*EXP(ETA(6))
KM = THETA(8)
RMAX = THETA(9)*EXP(ETA(7))
KSS = THETA(10)
KDEG = THETA(11)*EXP(ETA(8))
KINT = THETA(12)*EXP(ETA(9))
KSYN = RMAX*KDEG
A_0(4) = RMAX
$DES
CONC = 0.5*(A(2)/V1-A(4)-KSS)+
0.5*SQRT((A(2)/V1-A(4)-KSS)**2+4*KSS*A(2)/V1)
DADT(1) =-KA*A(1)
DADT(2) = KA*A(1)-(K+K12)*CONC*V1+K21*A(3)-
KINT*CONC*V1*A(4)/(KSS+CONC)-VM*CONC*V1/(KM+CONC)
DADT(3) = K12*CONC*V1-K21*A(3)
DADT(4) = KSYN - KDEG*A(4) - (KINT-KDEG)*CONC*A(4)/(KSS+CONC)
$ERROR
CC=0.5*(A(2)/V1-A(4)-KSS)+
0.5*SQRT((A(2)/V1-A(4)-KSS)**2+4*KSS*A(2)/V1)
IF(TYPE.EQ.1) Y = LOG(CC)+EPS(1)
IF(TYPE.EQ.2) Y = LOG(A(4))+EPS(2)
$THETA
(0,0.300) ; 1 CL
(0,3.0000) ; 2 V1
(0,0.200) ; 3 Q
(0,3.0000) ; 4 V2
(0,0.7000) ; 5 F1
(0,0.5000) ; 6 KA
(0,1.5000) ; 7 VMAX
(0,3.0000) ; 8 KM
(0,0.1000) ; 9 RMAX
(0,0.015) ; 10 KSS
(0,10.00) ; 11 KDEG
(0,0.0500) ; 12 KINT
$OMEGA
0.04 ;1 CL
0.04 ;2 V1
0.04 ;3 Q
0.04 ;4 V2
0.04 ;5 KA
0.04 ;6 VM
0.04 ;7 RMAX
0.04 ;8 KDEG
0.04 ;9 KINT
$SIGMA
0.0225
0.04
$SIMULATION (20002) (333333 UNIFORM) ONLYSIM SUBPROBLEMS=1
$TABLE ID TIME IPRED ONEHEADER NOAPPEND NOPRINT FILE=../201sim.tab
Nonmem code of the two-target estimation model with MU-referencing:
$PROBLEM 201focei, QSS+MM model FOCEI
$INPUT C,ID,TIME,AMT,CON,DV,EVID,MDV,CMT,TYPE
$DATA ../../Data/DerivedData/SimulatedNonmemDataQSS2.csv IGNORE = C
$SUBROUTINES ADVAN13 TOL=9
$MODEL
COMP(COMP1)
COMP(COMP2)
COMP(COMP3)
COMP(COMP4)
$PK
MU_1 = THETA(1)
MU_2 = THETA(2)
MU_3 = THETA(3)
MU_4 = THETA(4)
MU_5 = THETA(5)
MU_6 = THETA(6)
MU_7 = THETA(7)
MU_8 = THETA(8)
MU_9 = THETA(9)
MU_10= THETA(10)
MU_11= THETA(11)
MU_12= THETA(12)
CL = EXP(MU_1+ETA(1))
V1 = EXP(MU_2+ETA(2))
Q = EXP(MU_3+ETA(3))
V2 = EXP(MU_4+ETA(4))
K = CL/V1
K12 = Q/V1
K21 = Q/V2
F1 = EXP(MU_5+ETA(5))
KA = EXP(MU_6+ETA(6))
VM = EXP(MU_7+ETA(7))
KM = EXP(MU_8+ETA(8))
RMAX = EXP(MU_9+ETA(9))
KSS = EXP(MU_10+ETA(10))
KDEG = EXP(MU_11+ETA(11))
KINT = EXP(MU_12+ETA(12))
KSYN = RMAX*KDEG
A_0(4) = RMAX
$DES
CONC = 0.5*(A(2)/V1-A(4)-KSS)+
0.5*SQRT((A(2)/V1-A(4)-KSS)**2+4*KSS*A(2)/V1)
DADT(1)=-KA*A(1)
DADT(2) = KA*A(1)-(K+K12)*CONC*V1+K21*A(3)-
KINT*CONC*V1*A(4)/(KSS+CONC)-VM*CONC*V1/(KM+CONC)
DADT(3) = K12*CONC*V1-K21*A(3)
DADT(4) = KSYN - KDEG*A(4) - (KINT-KDEG)*CONC*A(4)/(KSS+CONC)
$ERROR
CC=0.5*(A(2)/V1-A(4)-KSS)+
0.5*SQRT((A(2)/V1-A(4)-KSS)**2+4*KSS*A(2)/V1)
Y=0
IF(TYPE.EQ.1) Y = LOG(CC)+EPS(1)
IF(TYPE.EQ.2) Y = LOG(A(4))+EPS(2)
$THETA
-0.9162907 ;1 CL 0.4
1.386294 ;2 V1 4.0
-1.203973 ;3 Q 0.3
0.6931472 ;4 V2 2.0
-0.2231436 ;5 F1 0.8
-0.5108256 ;6 KA 0.6
-0.6931472 ;7 VMAX 0.5
0.04879016 ;8 KM 1.05
-0.6931472 ;9 RMAX 0.5
-1.8971200 ;10 KSS 0.15
1.6094379 ;11 KDEG 5.0
-0.6931472 ;12 KINT 0.5
$OMEGA
0.1 ;1 CL
0.1 ;2 V1
0.1 ;3 Q
0.1 ;4 V2
0.1
0.1 ;6 KA
0.1 ;7 VM
0.1
0.1 ;9 RMAX
0.1
0.1 ;11 KDEG
0.14 ;12 KINT
$SIGMA
0.1
0.1
$EST MAXEVAL=9999 METHOD=1 INTERACTION NSIG=3 SIGL=9
NOABORT PRINT=10 FILE=201focei.ext MSFO=FILE.MSF
$COV PRINT=E SIGL=15 MATRIX=S UNCONDITIONAL
$TABLE ID TIME TYPE IPRED
ETA1 ETA2 ETA3 ETA4 ETA5 ETA6 ETA7 ETA8 ETA9 ETA10 ETA11 ETA12
ONEHEADER NOPRINT FILE=../201focei.tab
Nonmem code of the one-target estimation model without MU-referencing:
$PROBLEM 401, QSS model
$INPUT C,ID,TIME,AMT,CON,DV,EVID,MDV,CMT,TYPE
$DATA ../../Data/DerivedData/SimulatedNonmemDataQSS2.csv IGNORE = C
$SUBROUTINES ADVAN13 TOL=9
$MODEL
COMP(COMP1)
COMP(COMP2)
COMP(COMP3)
COMP(COMP4)
$PK
CL = THETA(1)*EXP(ETA(1))
V1 = THETA(2)*EXP(ETA(2))
Q = THETA(3)*EXP(ETA(3))
V2 = THETA(4)*EXP(ETA(4))
K = CL/V1
K12 = Q/V1
K21 = Q/V2
F1 = THETA(5)*EXP(ETA(5))
KA = THETA(6)*EXP(ETA(6))
RMAX = THETA(7)*EXP(ETA(7))
KSS = THETA(8)*EXP(ETA(8))
KDEG = THETA(9)*EXP(ETA(9))
KINT = THETA(10)*EXP(ETA(10))
KSYN = RMAX*KDEG
A_0(4) = RMAX
$DES
CONC = 0.5*(A(2)/V1-A(4)-KSS)+
0.5*SQRT((A(2)/V1-A(4)-KSS)**2+4*KSS*A(2)/V1)
DADT(1)=-KA*A(1)
DADT(2)= KA*A(1)-(K+K12)*CONC*V1+K21*A(3)-KINT*CONC*V1*A(4)/(KSS+CONC)
DADT(3)= K12*CONC*V1-K21*A(3)
DADT(4)= KSYN - KDEG*A(4) - (KINT-KDEG)*CONC*A(4)/(KSS+CONC)
$ERROR
CC=0.5*(A(2)/V1-A(4)-KSS)+
0.5*SQRT((A(2)/V1-A(4)-KSS)**2+4*KSS*A(2)/V1)
Y=0
IF(TYPE.EQ.1) Y = LOG(CC)+EPS(1)
IF(TYPE.EQ.2) Y = LOG(A(4))+EPS(2)
$THETA
(0,0.400) ; 1 CL
(0,4.0000) ; 2 V1
(0,0.300) ; 3 Q
(0,2.0000) ; 4 V2
(0,0.8000) ; 5 F1
(0,0.6000) ; 6 KA
(0,0.5000) ; 7 VMAX
(0,0.15) ; 8 KSS
(0,5.000) ; 9 KDEG
(0,0.500) ; 10 KINT
$OMEGA
0.1 ;1 CL
0.1 ;2 V1
0.1 ;3 Q
0.1 ;4 V2
0.1 ;5 F1
0.1 ;6 KA
0.1 ;7 RMAX
0.1 ;8 KSS
0.1 ;9 KDEG
0.1 ;10 KINT
$SIGMA
0.1
0.1
$EST MAXEVAL=99999 METHOD=1 INTERACTION NSIG=3 SIGL=9
NOABORT PRINT=10 FILE=401.ext MSFO=FILE.MSF
$COV PRINT=E SIGL=15 MATRIX=S UNCONDITIONAL
$TABLE ID TIME TYPE IPRED
ETA1 ETA2 ETA3 ETA4 ETA5 ETA6 ETA7 ETA8 ETA9 ETA10
ONEHEADER NOPRINT FILE=../401.tab
Nonmem data item definitions
Column / DescriptionC / “.” for records used in the analysis; “C” for records ignored by NONMEM
ID / Unique subject identifier
TIME / Time after the first dose (days)
AMT / NONMEM data item, dose (mg) for dosing records, 0 otherwise
CONC / Observed concentrations (ng/mL) for observation records, 0 otherwise
DV / Logarithm of observed concentrations (ng/mL) for observation records, 0 otherwise
EVID / NONMEM data item (1 = dose record, 0 = observation record)
MDV / NONMEM data item (1 = missing dependent variable, 0 = observation available)
CMT / NONMEM data item (1 = depot compartment, 2 = drug central compartment, 4 = S-target compartment)
TYPE / Observation type (0 = dose record, 1 = drug, 2 = S-target)
Nonmem dataset subset with data for 1 subject
C / ID / TIME / AMT / CONC / DV / EVID / MDV / CMT / TYPE. / 1 / 0 / 100 / 0 / 0 / 1 / 1 / 2 / 0
. / 1 / 0.0417 / 0 / 21.6 / 3.07 / 0 / 0 / 2 / 1
. / 1 / 0.0417 / 0 / 0.129 / -2.05 / 0 / 0 / 4 / 2
. / 1 / 0.25 / 0 / 26.7 / 3.29 / 0 / 0 / 2 / 1
. / 1 / 0.25 / 0 / 0.269 / -1.31 / 0 / 0 / 4 / 2
. / 1 / 0.5 / 0 / 21.9 / 3.09 / 0 / 0 / 2 / 1
. / 1 / 0.5 / 0 / 0.377 / -0.976 / 0 / 0 / 4 / 2
. / 1 / 1 / 0 / 13.8 / 2.63 / 0 / 0 / 2 / 1
. / 1 / 1 / 0 / 1.13 / 0.122 / 0 / 0 / 4 / 2
. / 1 / 3 / 0 / 11.2 / 2.42 / 0 / 0 / 2 / 1
. / 1 / 3 / 0 / 3.03 / 1.11 / 0 / 0 / 4 / 2
. / 1 / 7 / 0 / 2.02 / 0.701 / 0 / 0 / 2 / 1
. / 1 / 7 / 0 / 3.01 / 1.1 / 0 / 0 / 4 / 2
. / 1 / 14 / 0 / 0.315 / -1.16 / 0 / 0 / 2 / 1
. / 1 / 14 / 0 / 3.94 / 1.37 / 0 / 0 / 4 / 2
. / 1 / 21 / 0 / 0.296 / -1.22 / 0 / 0 / 2 / 1
. / 1 / 21 / 0 / 2.52 / 0.924 / 0 / 0 / 4 / 2
. / 1 / 28 / 0 / 0.177 / -1.73 / 0 / 0 / 2 / 1
. / 1 / 28 / 0 / 2.19 / 0.783 / 0 / 0 / 4 / 2
. / 1 / 35 / 0 / 0.124 / -2.09 / 0 / 0 / 2 / 1
. / 1 / 35 / 0 / 1.33 / 0.287 / 0 / 0 / 4 / 2
. / 1 / 42 / 0 / 0.0777 / -2.56 / 0 / 0 / 2 / 1
. / 1 / 42 / 0 / 0.862 / -0.148 / 0 / 0 / 4 / 2
. / 1 / 49 / 0 / 0.0675 / -2.7 / 0 / 0 / 2 / 1
. / 1 / 49 / 0 / 0.736 / -0.307 / 0 / 0 / 4 / 2
. / 1 / 56 / 0 / 0.0361 / -3.32 / 0 / 0 / 2 / 1
. / 1 / 56 / 0 / 0.522 / -0.649 / 0 / 0 / 4 / 2