Spousal Similarity in Life Satisfaction 1

SPOUSAL SIMILARITY IN LIFE SATISFACTION 1

Appendix A

Syntax for Dyadic, Multi-Period STARTS Model

Mplus VERSION 7.11

MUTHEN & MUTHEN

INPUT INSTRUCTIONS

TITLE: Five-Year Dyadic STARTS for Divorce;

DATA: FILE = "”;

VARIABLE:

NAMES = lsH5b lsW5b lsH4b lsW4b lsH3b lsW3b lsH2b lsW2b

lsH1b lsW1b lsH0a lsW0a lsH1a lsW1a lsH2a lsW2a lsH3a lsW3a

lsH4a lsW4a kidflag;

usevariables lsH5b lsW5b lsH4b lsW4b lsH3b lsW3b lsH2b lsW2b

lsH1b lsW1b lsH0a lsW0a lsH1a lsW1a lsH2a lsW2a lsH3a lsW3a

lsH4a lsW4a;

MISSING=.;

ANALYSIS:

ITERATIONS = 1000;

CONVERGENCE = 0.00005;

ESTIMATOR = ML;

! COVERAGE = .05;

MODEL:

!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!

! Husband Model

!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!;

! Create a latent factor for each observed variable;

! Before divorce;

hlslat5b by lsH5b@1;

hlslat4b by lsH4b@1;

hlslat3b by lsH3b@1;

hlslat2b by lsH2b@1;

hlslat1b by lsH1b@1;

! After divorce;

hlslat0a by lsH0a@1;

hlslat1a by lsH1a@1;

hlslat2a by lsH2a@1;

hlslat3a by lsH3a@1;

hlslat4a by lsH4a@1;

! Fix residual observed variance to be equal

! First set to be equal within period

! Can later constrain this

lsH5b*1 (herror1);

lsH4b*1 (herror1);

lsH3b*1 (herror1);

lsH2b*1 (herror1);

lsH1b*1 (herror1);

lsH0a*1 (herror2);

lsH1a*1 (herror2);

lsH2a*1 (herror2);

lsH3a*1 (herror2);

lsH4a*1 (herror2);

! Create latent trait factor

htrait by hlslat5b@1;

htrait by hlslat4b@1;

htrait by hlslat3b@1;

htrait by hlslat2b@1;

htrait by hlslat1b@1;

htrait by hlslat0a@1;

htrait by hlslat1a@1;

htrait by hlslat2a@1;

htrait by hlslat3a@1;

htrait by hlslat4a@1;

htrait*1 (htraitVar);

! Set up autoregressive factors

har5b by hlslat5b@1;

har4b by hlslat4b@1;

har3b by hlslat3b@1;

har2b by hlslat2b@1;

har1b by hlslat1b@1;

har0a by hlslat0a@1;

har1a by hlslat1a@1;

har2a by hlslat2a@1;

har3a by hlslat3a@1;

har4a by hlslat4a@1;

! Define autoregressive structure

har4b on har5b*.7 (hstabpr);

har3b on har4b*.7 (hstabpr);

har2b on har3b*.7 (hstabpr);

har1b on har2b*.7 (hstabpr);

har0a on har1b*.7 (hstabtr);

har1a on har0a*.7 (hstabpo);

har2a on har1a*.7 (hstabpo);

har3a on har2a*.7 (hstabpo);

har4a on har3a*.7 (hstabpo);

! Set residual variance of true scores to zero

hlslat5b@0;

hlslat4b@0;

hlslat3b@0;

hlslat2b@0;

hlslat1b@0;

hlslat0a@0;

hlslat1a@0;

hlslat2a@0;

hlslat3a@0;

hlslat4a@0;

! Set name for initial AR variance (for later constraint)

har5b*1 (hArVar);

har0a*1 (hArVar2);

! Impose equality constraint on residual variances for each occasion

har4b*.3 (hArVarPr);

har3b*.3 (hArVarPr);

har2b*.3 (hArVarPr);

har1b*.3 (hArVarPr);

!har0a*.3 (hArVarPo);

har1a*.3 (hArVarPo);

har2a*.3 (hArVarPo);

har3a*.3 (hArVarPo);

har4a*.3 (hArVarPo);

!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!

! Wife Model

!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!

! Create a latent factor for each observed variable

! Before divorce

wlslat5b by lsW5b@1;

wlslat4b by lsW4b@1;

wlslat3b by lsW3b@1;

wlslat2b by lsW2b@1;

wlslat1b by lsW1b@1;

! After divorce

wlslat0a by lsW0a@1;

wlslat1a by lsW1a@1;

wlslat2a by lsW2a@1;

wlslat3a by lsW3a@1;

wlslat4a by lsW4a@1;

! Fix residual observed variance to be equal

! First set to be equal within period

! Can later constrain this

lsW5b*1 (werror1);

lsW4b*1 (werror1);

lsW3b*1 (werror1);

lsW2b*1 (werror1);

lsW1b*1 (werror1);

lsW0a*1 (werror2);

lsW1a*1 (werror2);

lsW2a*1 (werror2);

lsW3a*1 (werror2);

lsW4a*1 (werror2);

! Create latent trait factor

wtrait by wlslat5b@1;

wtrait by wlslat4b@1;

wtrait by wlslat3b@1;

wtrait by wlslat2b@1;

wtrait by wlslat1b@1;

wtrait by wlslat0a@1;

wtrait by wlslat1a@1;

wtrait by wlslat2a@1;

wtrait by wlslat3a@1;

wtrait by wlslat4a@1;

wtrait*1 (wtraitVar);

! Set up autoregressive factors

war5b by wlslat5b@1;

war4b by wlslat4b@1;

war3b by wlslat3b@1;

war2b by wlslat2b@1;

war1b by wlslat1b@1;

war0a by wlslat0a@1;

war1a by wlslat1a@1;

war2a by wlslat2a@1;

war3a by wlslat3a@1;

war4a by wlslat4a@1;

! Define autoregressive structure

war4b on war5b*.7 (wstabpr);

war3b on war4b*.7 (wstabpr);

war2b on war3b*.7 (wstabpr);

war1b on war2b*.7 (wstabpr);

war0a on war1b*.7 (wstabtr);

war1a on war0a*.7 (wstabpo);

war2a on war1a*.7 (wstabpo);

war3a on war2a*.7 (wstabpo);

war4a on war3a*.7 (wstabpo);

! Set residual variance of true scores to zero

wlslat5b@0;

wlslat4b@0;

wlslat3b@0;

wlslat2b@0;

wlslat1b@0;

wlslat0a@0;

wlslat1a@0;

wlslat2a@0;

wlslat3a@0;

wlslat4a@0;

! Set name for initial AR variance (for later constraint)

war5b*1 (wArVar);

war0a*1 (wArVar2);

! Impose equality constraint on residual variances for each occasion

war4b*.3 (warVarPr);

war3b*.3 (warVarPr);

war2b*.3 (warVarPr);

war1b*.3 (warVarPr);

!war0a*.3 (warVarPo);

war1a*.3 (warVarPo);

war2a*.3 (warVarPo);

war3a*.3 (warVarPo);

war4a*.3 (warVarPo);

!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!

! Dyadic Part of Model

!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!

! Stable Trait

htrait with wtrait*.6 (UTSIM);

! Initial AR

har5b with war5b*.5 (UISIM);

! New AR

har4b with war4b*.3 (UNSIM1);

har3b with war3b*.3 (UNSIM1);

har2b with war2b*.3 (UNSIM1);

har1b with war1b*.3 (UNSIM1);

har0a with war0a*.3 (UNSIMT);

har1a with war1a*.3 (UNSIM2);

har2a with war2a*.3 (UNSIM2);

har3a with war3a*.3 (UNSIM2);

har4a with war4a*.3 (UNSIM2);

! State/Error

lsH5b with lsW5b (UESIM1);

lsH4b with lsW4b (UESIM1);

lsH3b with lsW3b (UESIM1);

lsH2b with lsW2b (UESIM1);

lsH1b with lsW1b (UESIM1);

lsH0a with lsW0a (UESIMT);

lsH1a with lsW1a (UESIM2);

lsH2a with lsW2a (UESIM2);

lsH3a with lsW3a (UESIM2);

lsH4a with lsW4a (UESIM2);

! Make sure factors are uncorrelated (override old Mplus default)

har5b,war5b with htrait@0;

har5b,war5b with wtrait@0;

!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!

! Model Constraints

!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!

MODEL CONSTRAINT:

! Nonlinear constraints for stationarity

! This assumes that stationarity only holds within period

! Husbands

hArVarPr = hArVar - (hArVar * hstabpr**2);

hArVarPo = (hArVar*hstabtr**2 + hArVar2) - ((hArVar*hstabtr**2 + hArVar2) * hstabpo**2);

! Wives

wArVarPr = wArVar - (wArVar * wstabpr**2);

wArVarPo = (wArVar*wstabtr**2 + wArVar2) - ((wArVar*wstabtr**2 + wArVar2) * wstabpo**2);

NEW (TSIM ISIM NSIM1 NSIM2 ESIM1 ESIM2 WREL HREL);

TSIM = UTSIM / sqrt (wtraitVar * htraitvar);

ISIM = UISIM / sqrt (wArVar * hArVar);

NSIM1 = UNSIM1 / sqrt (wArVarPr * hArVarPr);

NSIM2 = UNSIM2 / sqrt (wArVarPo * hArVarPo);

ESIM1 = UESIM1 / sqrt (werror1 * herror1);

ESIM2 = UESIM2 / sqrt (werror2 * herror2);

WREL = (wtraitVar + wArVar) / (wtraitVar + wArVar + werror1);

HREL = (htraitVar + hArVar) / (htraitVar + hArVar + herror1);

! Add any additional equality constraints here.

wtraitvar = htraitvar;

werror1 = herror1;

werror2 = herror2;

werror1 = werror2;

wArVarPo = wArVarPr;

!hArVarPo = hArVarPr; !this significantly increases misfit

!hArVarPr = wArVarPr; !this significantly increases misfit

hArVarPo = wArVarPo;

UNSIM2 = 0;

UESIM2 = 0;

OUTPUT: RESIDUAL STANDARDIZED CINTERVAL TECH3 TECH4 SAMPSTAT;