Supplemental digital content
1
NONMEM CONTROL STREAMS
Population pharmacokinetic model (Run 10)
$PROBLEM XL184 PK,2-comp with first-order absorption (Base)
$INPUT C STUD PERI DOSE ID PT DAY=DROP ADAY HOUR TIME CONC DV
EVID MDV AMT ADDL II FLGPK=DROP IMPUTE=DROP
$INPUT PKDATE=DROP PKTIME=DROP FDHD=DROP FLAG=DROP FOOD AGE SEX
WT RACE HT=DROP
$INPUT SMOK BMI BSA BIL CREA=DROP CRCL ALT AST ALB
$DATA 20140427.xl184poppk.exclfed.v4.csv IGNORE=C
IGNORE(ID.EQ.292)
$SUBROUTINE ADVAN4 TRANS4
$PK
POP = 0
IF (STUD.EQ.4) POP = 1
IF (STUD.EQ.6) POP = 1
IF (STUD.EQ.7) POP = 1
COVCL = (1+ THETA(7)*(SEX-1))*(EXP(THETA(8)*(BMI-24.8)))*(EXP(THETA(9)*POP))
TVCL = THETA(1)
CL=TVCL*COVCL*DEXP(ETA(1))
TVV2 = THETA(2)
V2=TVV2*DEXP(ETA(2))
Q = THETA(3)
TV3 = THETA(4)
V3 = TV3
KA=THETA(5)*DEXP(ETA(3))
ALAG1=THETA(6)/2.4D01
S2=V2/1.D03
K10 = CL/V2
K12 = Q/V2
K21 = Q/V3
AA = K10+K12+K21
RRD = (AA+(AA*AA-4*K10*K21)**0.5)/2
RRE = (AA-(AA*AA-4*K10*K21)**0.5)/2
T12E = LOG(2)/RRE
T12D = LOG(2)/RRD
IF(AMT.GT.0) TDOS=TIME
TAD=TIME-TDOS
$ERROR
TY=F
IF(F.GT.0) THEN
IPRED=DLOG(F)
ELSE
IPRED=0
ENDIF
IRES=DV-IPRED
Y=IPRED+ EPS(1)
$THETA (0,70) ; CL
(0,349.305) ; V2
(0,20) ; Q
(0,200) ; v3
(0,62.7934) ; KA
(0,0.471162) ; ALAG1
(-0.5,-0.1,0.5) ; SEX ON CL
0.1 ; BMI on CL
0.1 ; HV on CL
$OMEGA BLOCK(2)
0.1
0.01 0.1
$OMEGA 0.1
$SIGMA 0.1
$ESTIMATION INTER MAX=9999 PRINT=5 METHOD=1 NSIG=3 SIGL=6
$COVARIANCE MATRIX=R UNCONDITIONAL
$TABLE STUD ID PT DOSE ADAY TIME TAD CONC TY IPRED IRES CWRES
NOPRINT ONEHEADER FILE=sdtab10
$TABLE STUD ID CL V2 Q V3 KA ALAG1 T12D T12E ETA(1) ETA(2) ETA(3)
NOPRINT FIRSTONLY ONEHEADER FILE=patab10
$TABLE STUD ID AGE WT BMI BSA BIL CRCL ALT AST ALB NOPRINT
FIRSTONLY ONEHEADER FILE=cotab10
$TABLE STUD ID DOSE SEX RACE SMOK NOPRINT FIRSTONLY ONEHEADER
FILE=catab10
$TABLE STUD ID PT DOSE ADAY TIME TAD EVID CONC TY IPRED IRES
CWRES CL V2 Q V3 KA ALAG1 T12D T12E ETA(1) ETA(2) ETA(3)
AGE WT BMI BSA BIL CRCL ALT AST ALB FOOD SEX RACE SMOK
NOPRINT ONEHEADER FILE=outab10.txt
Semi-mechanistic model (model 28)
$PROBLEM NONMEM PROBLEM DEFINITION
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
; 1NONLINEAR MIXED EFFECTS MODEL PROGRAM (NONMEM) VERSION 7.1.0 ;
;------MODEL & DATA DESCRIPTION------;
;
;TIME: days
;CONC: ng/ml
;DV: mm (tumor volume)
;AMT: mg x 0.789
;PK model: XL184 PK,2-comp with first-order absorption (Final run10.mod)
;
;------END MODEL DESCRIPTION------
;
$INPUT C STUD ID PT TIME DV LNDV EVID MDV AMT ADDL II TV BTV LBTV
AGE SEX WT RACE HT SMOK BMI BSA TYPE TRT CLi VCi Qi VPi
KAi ALAGi
;
;$DATA Y:\184\301\POP-PK-T\FILES\PKPD-025-NS\PKPD-025-NS-D.csv IGNORE=@
$DATA 20140604.xl184pkpdQC.csv IGNORE=C WIDE
IGNORE=(TIME.GT.614)
;
$SUBROUTINE ADVAN6 TOL=3
;
$MODEL NCOMP=4 COMP=(DEP,DEFDOSE) ;CMT1 is depot site
COMP=(CENT) ;CMT2 is obs site
COMP=(PERIPH) ;CMT3 is PK peripheral compartment
COMP=(TVLM,DEFOBS) ;CMT4 is TUMOR BURDEN
;
$PK
;
;Pharmacokinetics (PK)
;READ run9.mod EBE's from PKPD database
;
CL=CLi
VC=VCi
Q=Qi
VP=VPi
KA=KAi
ALAG1=ALAGi ; RW
;
;Tumor burden dynamics (PD)
; baseline tumor volume (mm)
TV0 = THETA(1)*EXP(EXP(THETA(5))*ETA(1))
; Net disease progression rate (1/1000d)
NDPR = THETA(2)+EXP(THETA(6))*ETA(2)
; Normalized 1/day
NDPRN = NDPR/1000
; Kill slope (1/1000d)/(ng/mL)
kK = EXP(THETA(3))*EXP(EXP(THETA(7))*ETA(3))
; Normalized 1/day
kKN = kK/1000; 1/d/(ng/mL)
; Resistance rate (1/1000d)
kR = EXP(THETA(8))*EXP(EXP(THETA(9))*ETA(4))
kRN = kR/1000
A_0(4) = TV0;INITIAL (ESTIMATED) TUMOR VOLUME (MM)
;
$DES
;
;------PK Mass Balance Eqtns------
;
CP=1.D03*A(2)/VC;UG/ML to NG/ML
INH=kKN*CP
IF(TRT.EQ.0) THEN;PLACEBO DATA ONLY
;Pharmacokinetics (PK)
DADT(1)=0.D0
DADT(2)=0.D0
DADT(3)=0.D0
;Tumor Size
DADT(4)=NDPRN*A(4)
ELSE;ACTIVE TREATMENT
;Pharmacokinetics (PK)
DADT(1)=-A(1)*KA
DADT(2)=KA*A(1)-A(2)*(CL/VC)-A(2)*Q/VC+A(3)*Q/VP
DADT(3)=A(2)*Q/VC-A(3)*Q/VP
;Tumor Size
DADT(4)=NDPRN*A(4)-INH*A(4)*EXP(-kRN*T)
ENDIF
;
$ERROR
;
IPRED=F
W=EXP(THETA(4))
IRES=DV-IPRED
IWRES=IRES/(W*IPRED)
Y=IPRED*(1.D0+ERR(1)*W)
;
$THETA 8.08E+01 ; THETAINIT 1 [TV0]
8.14E-01 ; THETAINIT 2 [NDPR]
-4.58E+00 ; THETAINIT 3 log(kk)
-2.62E+00 ; THETAINIT 4 Log of sd of proportional sigma on tumor
-2.63E-01 ; THETAINIT Log of sd of log-normal eta on TV0
3.18E-01 ; THETAINIT Log of sd of additive eta on NDPR
-4.26E-01 ; THETAINIT Log of sd on log-normal eta on kK
2.89E+00 ; THETAINIT log(kR)
-1 FIX ; THETAINIT Log of sd on log-normal eta on kR
$OMEGA 1 FIX ; OMEGAINIT TV0
1 FIX ; OMEGAINIT NDPR
1 FIX ; OMEGAINIT kK
0 FIX ; OMEGAINIT kR
$SIGMA 1 FIX ; SIGMAINIT
;
$ESTIMATION INTER MAX=9990 PRINT=1 METHOD=COND POSTHOC NOABORT NSIG=3
SIGL=6 ;EVAL
$COVARIANCE
$TABLE STUD ID PT TRT AGE SEX WT BMI BSA BTV CL VC Q VP KA ALAG1
TV0 kK kR ETA1 ETA2 ETA3 ETA4 NOPRINT NOAPPEND ONEHEADER
FIRSTONLY FILE=pat28.txt
$TABLE STUD ID PT TRT TIME TYPE DV MDV AMT CP INH TIME IPRED PRED
IWRES CWRES NDPR NOPRINT NOAPPEND ONEHEADER
FILE=pred28.txt
Semi-empirical model - cabozantinib treatment arm (model 104)
$PROBLEM NONMEM PROBLEM DEFINITION
;------MODEL & DATA DESCRIPTION------;
;
;TIME: days
;CONC: ng/ml
;DV: mm (tumor volume)
;AMT: mg x 0.789
;PK model: XL184 PK,2-comp with first-order absorption (Final run10.mod)
;------END MODEL DESCRIPTION------
;
$INPUT C STUD ID PT TIME DV LNDV EVID MDV AMT ADDL II TV BTV LBTV
AGE SEX WT RACE HT SMOK BMI BSA ;INPUT
TYPE TRT CLi VCi Qi VPi KAi ALAGi ;INPUT
;
$DATA 20140604.xl184pkpdQC.csv IGNORE=@ IGNORE(TIME.GT.614)
IGNORE(TRT.EQ.0)
$SUBROUTINE ADVAN6 TOL=3
;
$MODEL NCOMP=6 COMP=(DEP,DEFDOSE) ;CMT1 is depot site
COMP=(CENT) ;CMT2 is obs site
COMP=(PERIPH) ;CMT3 is PK peripheral compartment
COMP=(TVLM,DEFOBS) ;CMT4 is TUMOR BURDEN
COMP=(AUC) ;CMT5 is AUC
COMP=(AUCPDC) ;CMT6 is PD AUC
;
$PK
CL=CLi
VC=VCi
Q=Qi
VP=VPi
KA=KAi
ALAG1=ALAGi
;
;Tumor burden dynamics (PD)
; baseline tumor volume (mm)
TV0 = THETA(1)*EXP(EXP(THETA(5))*ETA(1))
; Net disease progression rate (1/1000d)
NDPR = THETA(2)+EXP(THETA(6))*ETA(2)
; Normalized 1/day
NDPRN = NDPR/1000
; Kill slope
INTER1 = THETA(3) + EXP(THETA(8))*ETA(3)
INTER1N = INTER1/1000
SLP1 = THETA(11) + EXP(THETA(14))*ETA(6)
SLP1N = SLP1/1000000
; Stabilization Rate
INTER2 = THETA(7) + EXP(THETA(9))*ETA(4)
INTER2N = INTER2/1000
SLP2 = THETA(12) + EXP(THETA(13))*ETA(5)
SLP2N = SLP2/1000000
; Split time
TSPL=THETA(10)
A_0(4) = TV0;INITIAL (ESTIMATED) TUMOR VOLUME (MM)
;
$DES
;------PK Mass Balance Eqtns------
CONC=1.0D03*A(2)/VC
IF(T.LE.TSPL) INHN=INTER1N + SLP1N * CONC
IF(T.GT.TSPL) INHN=INTER2N + SLP2N * CONC
IF(TRT.EQ.0) THEN;PLACEBO DATA ONLY
;Pharmacokinetics (PK)
DADT(1)=0.D0
DADT(2)=0.D0
DADT(3)=0.D0
;Tumor Size
DADT(4)=NDPRN*A(4)
DADT(6)=(A(4)-TV0)/TV0
ENDIF
IF(TRT.EQ.1)THEN;ACTIVE TREATMENT
;Pharmacokinetics (PK)
DADT(1)=-A(1)*KA
DADT(2)=KA*A(1)-A(2)*(CL/VC)-A(2)*Q/VC+A(3)*Q/VP
DADT(3)=A(2)*Q/VC-A(3)*Q/VP
DADT(5)=CONC
ENDIF
;Tumor Size
IF(TRT.EQ.1) THEN
DADT(4)=(INHN)*A(4)
DADT(6)=(A(4)-TV0)/TV0
ENDIF
$ERROR
;
;calculate target concentration
IF(TRT.EQ.1) THEN
CP=1D03*A(2)/VC
AUC=A(5)
ENDIF
AUCPD=A(6)
IPRED=F
W=exp(THETA(4))
IRES=DV-IPRED
IWRES=IRES/(W*IPRED)
Y=IPRED*(1.D0+ERR(1)*W)
;
$THETA 9.35E+01 ; THETAINIT 1 [TV0]
0 FIX ; THETAINIT 2 [NDPR]
-1.69E+00 ; THETAINIT 3 [INTER1]
-2.41E+00 ; THETAINIT 4 Log of sd of proportional sigma on tumor
-2.96E-01 ; THETAINIT 5 Log of sd of log-normal eta on TV0
-200 FIX ; THETAINIT 6 Log of sd of additive eta on NDPR
5.92E-01 ; THETAINIT 7 [INTER2]
5.75E-02 ; THETAINIT 8 Log of sd of additive eta on INTER1
-5.78E-01 ; THETAINIT 9 Log of sd of additive eta on INTER2
110 FIX ; THETAINIT 10 split time
0 FIX ; THETAINIT 11 [SLP1]
9.06E-01 ; THETAINIT 12 [SLP2]
-5.53E-01 ; THETAINIT 13 [SLP2] Log of sd of log-normal eta on SLP2
0 FIX ; THETAINIT 14 [SLP1] Log of sd of log-normal eta on SLP1
$OMEGA 1 FIX ; OMEGAINIT TV0
1 FIX ; OMEGAINIT NDPR
1 FIX ; OMEGAINIT INTER1
1 FIX ; OMEGAINIT INTER2
1 FIX ; OMEGAINIT S2
0 FIX ; OMEGAINIT S1
$SIGMA 1 FIX ; SIGMAINIT
;
$ESTIMATION INTER MAX=9990 PRINT=1 METHOD=COND POSTHOC NOABORT NSIG=3
SIGL=6 ;EVAL
;COVA
$COVARIANCE
$TABLE STUD ID TRT TIME AMT CP LNDV MDV IPRED IWRES,CWRES NDPR
SLP1 SLP2 TSPL AUC AUCPD TV BTV NOPRINT ONEHEADER
FILE=104-NSA.TXT ;FILEA
$TABLE STUD ID PT TIME NDPR NDPRN INTER1 INTER1N INTER2 INTER2N
SLP1 SLP1N SLP2 SLP2N TSPL NOPRINT ONEHEADER
FILE=104-NSC.TXT ;FILEC
$TABLE ID PT CL VC Q VP KA ALAG1 ETA1 ETA2 ETA3 ETA4 ETA5 ETA6
NOPRINT ONEHEADER FILE=104-NSE.TXT ;FILEE
$TABLE STUD ID PT AGE SEX WT BMI BSA TYPE TRT TV0 BTV NOPRINT
ONEHEADER FILE=104-NSF.TXT ;FILEF
Semi-empirical model - placebo arm (model 101)
$PROBLEM NONMEM PROBLEM DEFINITION
;------MODEL & DATA DESCRIPTION------;
;
;TIME: days
;CONC: ng/ml
;DV: mm (tumor volume)
;AMT: mg x 0.789
;PK model: XL184 PK,2-comp with first-order absorption (Final run10.mod)
;------END MODEL DESCRIPTION------
;
$INPUT C STUD ID PT TIME DV LNDV EVID MDV AMT ADDL II TV BTV LBTV
AGE SEX WT RACE HT SMOK BMI BSA ;INPUT
TYPE TRT CLi VCi Qi VPi KAi ALAGi ;INPUT
;
$DATA 20140604.xl184pkpdQC.csv IGNORE=@ IGNORE(TIME.GT.614)
IGNORE(TRT.EQ.1)
$SUBROUTINE ADVAN6 TOL=3
;
$MODEL NCOMP=6 COMP=(DEP,DEFDOSE) ;CMT1 is depot site
COMP=(CENT) ;CMT2 is obs site
COMP=(PERIPH) ;CMT3 is PK peripheral compartment
COMP=(TVLM,DEFOBS) ;CMT4 is TUMOR BURDEN
COMP=(AUC) ;CMT5 is AUC
COMP=(AUCPDC) ;CMT6 is PD AUC
;
$PK
CL=CLi
VC=VCi
Q=Qi
VP=VPi
KA=KAi
ALAG1=ALAGi
;
;Tumor burden dynamics (PD)
; baseline tumor volume (mm)
TV0 = THETA(1)*EXP(EXP(THETA(5))*ETA(1))
; Net disease progression rate (1/1000d)
NDPR = THETA(2)+EXP(THETA(6))*ETA(2)
; Normalized 1/day
NDPRN = NDPR/1000
; Kill slope
INTER1 = THETA(3) + EXP(THETA(8))*ETA(3)
INTER1N = INTER1/1000
SLP1 = THETA(11) + EXP(THETA(14))*ETA(6)
SLP1N = SLP1/1000000
; Stabilization Rate
INTER2 = THETA(7) + EXP(THETA(9))*ETA(4)
INTER2N = INTER2/1000
SLP2 = THETA(12) + EXP(THETA(13))*ETA(5)
SLP2N = SLP2/1000000
; Split time
TSPL=THETA(10)
A_0(4) = TV0;INITIAL (ESTIMATED) TUMOR VOLUME (MM)
;
$DES
;------PK Mass Balance Eqtns------
CONC=1.0D03*A(2)/VC
IF(T.LE.TSPL) INHN=INTER1N + SLP1N * CONC
IF(T.GT.TSPL) INHN=INTER2N + SLP2N * CONC
IF(TRT.EQ.0) THEN;PLACEBO DATA ONLY
;Pharmacokinetics (PK)
DADT(1)=0.D0
DADT(2)=0.D0
DADT(3)=0.D0
;Tumor Size
DADT(4)=NDPRN*A(4)
DADT(6)=(A(4)-TV0)/TV0
ENDIF
IF(TRT.EQ.1)THEN;ACTIVE TREATMENT
;Pharmacokinetics (PK)
DADT(1)=-A(1)*KA
DADT(2)=KA*A(1)-A(2)*(CL/VC)-A(2)*Q/VC+A(3)*Q/VP
DADT(3)=A(2)*Q/VC-A(3)*Q/VP
DADT(5)=CONC
ENDIF
;Tumor Size
IF(TRT.EQ.1) THEN
DADT(4)=(INHN)*A(4)
DADT(6)=(A(4)-TV0)/TV0
ENDIF
$ERROR
;
;calculate target concentration
IF(TRT.EQ.1) THEN
CP=1D03*A(2)/VC
AUC=A(5)
ELSE
AUC=0
ENDIF
AUCPD=A(6)
IPRED=F
W=exp(THETA(4))
IRES=DV-IPRED
IWRES=IRES/(W*IPRED)
Y=IPRED*(1.D0+ERR(1)*W)
;
$THETA 9.35E+01 ; THETAINIT 1 [TV0]
0.01 ; THETAINIT 2 [NDPR]
0 FIX ; THETAINIT 3 [INTER1]
-2.41E+00 ; THETAINIT 4 Log of sd of proportional sigma on tumor
-2.96E-01 ; THETAINIT 5 Log of sd of log-normal eta on TV0
0.5 ; THETAINIT 6 Log of sd of additive eta on NDPR
0 FIX ; THETAINIT 7 [INTER2]
0 FIX ; THETAINIT 8 Log of sd of additive eta on INTER1
0 FIX ; THETAINIT 9 Log of sd of additive eta on INTER2
110 FIX ; THETAINIT 10 split time
0 FIX ; THETAINIT 11 [SLP1]
0 FIX ; THETAINIT 12 [SLP2]
0 FIX ; THETAINIT 13 [SLP2] Log of sd of log-normal eta on SLP2
0 FIX ; THETAINIT 14 [SLP1] Log of sd of log-normal eta on SLP1
$OMEGA 1 FIX ; OMEGAINIT TV0
1 FIX ; OMEGAINIT NDPR
1 FIX ; OMEGAINIT INTER1
1 FIX ; OMEGAINIT INTER2
1 FIX ; OMEGAINIT S2
1 FIX ; OMEGAINIT S1
$SIGMA 1 FIX ; SIGMAINIT
;
$ESTIMATION INTER MAX=9990 PRINT=1 METHOD=COND POSTHOC NOABORT NSIG=3
SIGL=6 ;EVAL
;COVA
$COVARIANCE
$TABLE STUD ID TRT TIME AMT CP LNDV MDV IPRED IWRES,CWRES NDPR
SLP1 SLP2 TSPL AUC AUCPD TV BTV NOPRINT ONEHEADER
FILE=101-NSA.TXT ;FILEA
$TABLE STUD ID PT TIME NDPR NDPRN INTER1 INTER1N INTER2 INTER2N
SLP1 SLP1N SLP2 SLP2N TSPL NOPRINT ONEHEADER
FILE=101-NSC.TXT ;FILEC
$TABLE ID PT CL VC Q VP KA ALAG1 ETA1 ETA2 ETA3 ETA4 ETA5 ETA6
NOPRINT ONEHEADER FILE=101-NSE.TXT ;FILEE
$TABLE STUD ID PT AGE SEX WT BMI BSA TYPE TRT TV0 BTV NOPRINT
ONEHEADER FILE=101-NSF.TXT ;FILEF
1