Supplemental information for De Miranda Silva C et al.: Development of an Enantioselective and Biomarker-Informed Translational Population Pharmacokinetic / Pharmacodynamic Model for Etodolac
Figure S1: Observed vs. individually predicted plasma concentrations (panels A and B) and transformed pain scores (panel C). Panel A shows S-etodolac, panel B R- etodolac, and panel C PAIN after administration of 300 and 400 mg racemic etodolac to healthy volunteers or of 200 and 400 mg to dental surgery patients. The green line represents the line of identity.
Figure S2: Normalized Prediction Distribution Errors (NPDE) for (A) S-etodolac, (B) R-etodolac and (C) PAIN after 200 mg, 300 mg and 400 mg racemic doses. Ideally, the NPDEs should be standard normally distributed with a mean of zero and 95% of the NPDEs falling symmetrically between -2 and +2.
Commented SADAPT code for the enantioselective PK/PD model
$PROJECT THIS WILL BE A TERRIFIC PROJECT
$DIFFEQ_DIF
SSTOM = X(1) ; Amount of S-eto in stomach, receives half of racemic dose
SINTS = X(2) ; Amount of S-eto in intestine as solid drug
SINTD = X(3) ; Amount of S-eto in intestine as dissolved drug
SDC1 = X(4)/V1S ; Concentration of S-eto in the central compartment
SDC2 = X(5)/V2S ; Concentration of S-eto in the peripheral compartment
RSTOM = X(6) ; Amount of R-eto in stomach, receives half of racemic dose
RINTS = X(7) ; Amount of R-eto in intestine as solid drug
RINTD = X(8) ; Amount of R-eto in intestine as dissolved drug
RDC1 = X(9)/V1R ; Concentration of R-eto in the central compartment
RDC2 = X(10)/V2R ; Concentration of R-eto in the peripheral compartment
PAIN = X(11) ; Transformed pain scale observations
IF (T.GT.0) THEN
REL1 = 1 + EMAXA*(T**40)/(TC50A**40+T**40) ; 1st change of gastric transit kinetics
REL2 = 1 + EMAXB*(T**40)/(TC50B**40+T**40) ; 2nd change of gastric transit kinetics
ELSE
REL1 = 1
REL2 = 1
ENDIF
VMAXT = VMAX0 * REL1 * REL2 ; VMAXT is the time-dependent maximum rate of drug release
; from stomach into intestine
KmmS= VMAXT/(AM50cov + SSTOM) ; Michaelis-Menten equation from stomach to intestine
KmmR= VMAXT/(AM50cov + RSTOM) ; for S and R etodolac
XP(1)= -KmmS*SSTOM
XP(2)= FRSOLID*KmmS*SSTOM - KDISSO*SINTS
XP(3)= FRDISSO*KmmS*SSTOM + KDISSO*SINTS - KA*SINTD
XP(4)= KA*SINTD - CLS*SDC1 - CLdS*SDC1 + CLdS*SDC2
XP(5)= CLdS*SDC1 - CLdS*SDC2
XP(6)= -KmmR*RSTOM
XP(7)= FRSOLID*KmmR*RSTOM - KDISSO*RINTS
XP(8)= FRDISSO*KmmR*RSTOM + KDISSO*RINTS - KA*RINTD
XP(9)= KA*RINTD - CLR*RDC1 - CLdR*RDC1 + CLdR*RDC2
XP(10)= CLdR*RDC1 - CLdR*RDC2
COXINH = (SDC1 / (IC50S + SDC1)) ; COX-2 inhibition by S-eto conc. in central comp.
; COX-2 dependent inhibition of PAIN production
IF (COXINH.GT.0) THEN
INHPAIN = COXINH**GAMMA/ (IC50PAIN** GAMMA + COXINH**GAMMA)
ELSE
INHPAIN = 0
ENDIF
XP(11)= KIN * (1 - INHPAIN) - KOUT*PAIN ; turnover model for PAIN
$OUTPUT_GLB
; Parameter conversion (including unit conversion, e.g. from min to h, as needed)
KOUT = LOG(2)/TOUT ; please see Table 1 for parameter explanations
KIN = BASELINEPAIN*KOUT
Ka = LOG(2)/T12abs*60
KDISSO = LOG(2)/T12dis*60
TC50B = TC50A + DELTC50
IF (DOSI.LT.175) THEN ; DOSI refers to the enantiomers (i.e. half of total dose)
FRDISSO = FRDIS300 ; Fraction leaving stomach as dissolved drug for 300 mg tablets
ELSE
FRDISSO = FRDIS400 ; Fraction leaving stomach as dissolved drug for 400 mg tablets
ENDIF
FRSOLID = 1 – FRDISSO
VMAXcov = VMAX * DOSI/150
AM50cov = AM50 * DOSI/150
$OUTPUT_ICS
X(11) = X(11) + BASEPAIN ; Initialization of the PAIN compartment
$OUTPUT_EQN
Y(1) = X(4)/V1S ; Observed S-eto concentration in the central compartment
Y(2) = X(9)/V1R ; Observed R-eto concentration in the central compartment
Y(3) = X(11) ; Link of observations at observation compartment 3 to PAIN
$VARMOD_EQN
V(1) = ( SDinS + SDslS*Y(1) ) * ( SDinS + SDslS*Y(1) )
V(2) = ( SDinR + SDslR*Y(2) ) * ( SDinR + SDslR*Y(2) )
V(3) = ( SDinP ) * ( SDinP )
$POPMOD_EQN
Berkeley Madonna code used for external model qualification with S-ibuprofen
; Systems model qualifying – COX-2 inhibition vs Pain
; Ibuprofen PK model from Loetsch et al., 2001
; Enantioselective model
; In vitro PD parameters for S-ibuprofen from Riendeau et al., 2001
; Clinical pain parameters from Mehlish et al. 1995
; Etodolac PD model to connect in vitro to clinical data
; PID converted to PAIN according to Boni et al., 1999
; => PAIN = 3-(PID -Placebo)
; Simulation to link S-ibuprofen to => COX activity => PAIN
; BSV ON PD
;#####################################################################
; Differential equation settings
Method STIFF
STARTTIME = 0
STOPTIME = 24
DT = 1e-3
DTMIN = 1e-5
DTMAX = 0.01
TOLERANCE = 0.00001
DTOUT = 0.1
;#####################################################################
; Parameter mean estimates and covariate effects (FIXED EFFECTS)
; Pharmacokinetic parameters from Literature for Ibuprofen enantiomers
Mean_ka = 1.52 ; 1/h Absorption rate constant
Mean_CLR = 4.90 ; L/h CL for R-ibuprofen
Mean_QR = 2.80 ; L/h Distribution CL for R-ibuprofen
Mean_CLS = 4.64 ; L/h CL for S-ibuprofen
Mean_QS = 4.10 ; L/h Distribution CL for S-ibuprofen
Mean_V1R = 5.10 ; L Volume of Central compartment for R-ibuprofen
Mean_V2R = 4.10 ; L Volume of Peripheral compartment for R-ibuprofen
Mean_V1S = 5.45 ; L Volume of Central compartment for S-ibuprofen
Mean_V2S = 5.20 ; L Volume of Peripheral compartment for S-ibuprofen
Mean_Fi = 0.60 ; Conversion of R-ibuprofen to S-ibuprofen
; In vitro parameter for COX-2 inhibition by ibuprofen
Mean_IC50S = 2.51; mg/L IC50 in vitro = 24.3 uM
; Acute pain System parameters estimated from etodolac model
Mean_BASELINEPAIN = 3.00 ; Baseline PAIN
Mean_IC50PAIN = 0.7845 ;
Mean_TOUT = 0.303 ; 1/h
Mean_GAMMA = 3.10 ; -
;#################
; Parameter variability estimates (coefficients of variation or SDs)
; Variability for in vitro IC50S from literature
CV_IC50COX= 0.381
; Variability for System model from Etodolac estimates
CV_BASELINEPAIN = 0.00621 ;
CV_IC50PAIN = 0.0923 ;
CV_TOUTPAIN = 0.775 ;
CV_HILLP = 0.146 ;
;#####################################################################
;# Monte Carlo part: Generation of random deviates
init ETA_IC50S = normal(0, CV_IC50S)
init ETA_BASELINEPAIN = normal(0, CV_BASELINEPAIN)
init ETA_IC50PAIN = normal(0, CV_IC50PAIN)
init ETA_TOUT = normal(0, CV_TOUT)
init ETA_GAMMA = normal(0, CV_GAMMA)
next ETA_IC50S = ETA_IC50S
next ETA_BASELINEPAIN = ETA_BASELINEPAIN
next ETA_IC50PAIN = ETA_IC50PAIN
next ETA_TOUT = ETA_TOUT
next ETA_GAMMA = ETA_GAMMA
Ka = Mean_Ka ;
CLR = Mean_CLR ;
QR = Mean_QR ;
CLS = Mean_CLS ;
QS = Mean_QS ;
V1R = Mean_V1R ;
V2R = Mean_V2R ;
V1S = Mean_V1S ;
V2S = Mean_V2S ;
Fi = Mean_Fi ;
IC50S = Mean_IC50S * EXP(ETA_IC50S)
BASELINEPAIN = Mean_BASELINEPAIN * EXP(ETA_BASELINEPAIN)
IC50PAIN = Mean_IC50PAIN * EXP(ETA_IC50PAIN)
TOUT = Mean_TOUT * EXP(ETA_TOUT)
GAMMA = Mean_GAMMA * EXP(ETA_GAMMA)
;#####################################################################
;# Drug input
DOSI = 200
; mg from 400 mg of RACEMIC Ibuprofen
INPUT_S = PULSE(DOSI,0,24)
INPUT_R = PULSE(DOSI,0,24)
;#####################################################################
;$PROJECT THIS WILL BE A TERRIFIC PROJECT
;$DIFFEQ_DIF
SSTOM = A_SSTOM ; Amount of S-ibu in stomach, equals half of racemic dose
SDC1 = A_SX1/V1S ; Amount of S-ibu in central compartment
SDC2 = A_SX2/V2S ; Amount of S-ibu in peripheral compartment
RSTOM = A_RSTOM ; Amount of R-ibu in stomach, equals half of racemic dose
RDC1 = A_RX1/V1R ; Amount of R-ibu in central compartment
RDC2 = A_RX2/V2R ; Amount of R-ibu in peripheral compartment
PAIN = A_PAIN ; Transformed pain scale observations
d/dt(A_SSTOM) = INPUT_S -Ka*SSTOM
d/dt(A_SX1) = Ka*SSTOM - CLS*SDC1 + CLRINV*RDC1 - QS*SDC1 + QS*SDC2
d/dt(A_SX2) = QS*SDC1 - QS*SDC2
d/dt(A_RSTOM) = INPUT_R -Ka*RSTOM
d/dt(A_RX1) = Ka*RSTOM - CLR*RDC1 - CLRINV*RDC1 - QR*RDC1 + QR*RDC2
d/dt(A_RX2) = QR*RDC1 - QR*RDC2
COXINH = (SDC1 / (IC50S + SDC1) ) ; COX-2 inhibition by S-ibu conc in central comp.
; COX-2 dependent inhibition of PAIN production
INHPAIN = IF (COX2INH > 0)
THEN COXINH**GAMMA / (IC50PAIN**GAMMA + COXINH**GAMMA)
ELSE 0
d/dt(A_PAIN) = KIN * (1 - INHPAIN) - KOUT*PAIN ; turnover model for PAIN
CLRINV = Fi*CLR ; Conversion Cl from R-ibu to S-ibu
; Parameter conversion (including unit conversion, e.g. from min to h, as needed)
KOUT = LOGN(2)/TOUT
KIN = BASELINEPAIN * KOUT
SC1 = A_SX1/V1S ; Observed S-ibu concentration in the central compartment
RC1 = A_RX1/V1R ; Observed R-ibu concentration in the central compartment
; initialization of compartments:
init A_PAIN = BASELINEPAIN
init A_RX1 = 0
init A_RX2 = 0
init A_SSTOM = 0
init A_SX1 = 0
init A_SX2 = 0
init A_RSTOM = 0